10 SITEDIR$ = "E:\GWB\GWBLOG\TEST"
500 REM =======================
501 REM Startup Code
502 REM =======================
509 REM Retrieve the current directory and configure subs
510 IF LEN(SITEDIR$) = 0 THEN GOSUB 15500 ELSE CURDIR$ = SITEDIR$
520 PAGEDIR$ = CURDIR$ + "\PAGES"
530 POSTDIR$ = CURDIR$ + "\POSTS"
540 STATICDIR$ = CURDIR$ + "\STATIC"
550 HDRFILE$ = CURDIR$ + "\POSTHDR.HTM"
560 FTRFILE$ = CURDIR$ + "\POSTFTR.HTM"
570 DESTDIR$ = CURDIR$ + "\BUILD"
700 REM =======================
701 REM Disk scanning
702 REM =======================

710 REM Scan pages first
720 DIREC$ = PAGEDIR$ + "\*.TXT"
730 GOSUB 15000
735 DIREC$ = PAGEDIR$
740 GOSUB 16000
750 DIM PAGES$[LC],PAGETIT$[LC]
760 PAGECNT=LC
770 FOR I=1 TO LC:PAGES$[I] = SFL$[I]:PAGETIT$[I] = TIT$[I]:NEXT I 

780 REM Scan posts
790 DIREC$ = POSTDIR$ + "\*.TXT"
800 GOSUB 15000
805 DIREC$ = POSTDIR$
810 GOSUB 16000
820 DIM POSTS$[LC],POSTTIT$[LC]
830 POSTCNT=LC
840 FOR I=1 TO LC:POSTS$[I] = SFL$[I]:POSTTIT$[I] = TIT$[I]:NEXT I 

900 REM =======================
901 REM Prepare template data
902 REM =======================
905 ILBL = 7
910 DIM LBL$[ILBL]
920 DIM REPL$[ILBL]
930 LBL$[1] = "title":REPL$[1] = "Blog!"
940 LBL$[2] = "next":REPL$[2] = ""
950 LBL$[3] = "previous":REPL$[3] = ""
960 LINKURL$ = POSTS$[POSTCNT]:LINKLBL$="Latest Post":GOSUB 19000
970 LBL$[4] = "latest":REPL$[4] = LINKHTM$
980 URLS$ = PAGES$:LBLS$ = PAGETIT$:URLCOUNT = PAGECNT:GOSUB 19100
990 LBL$[5] = "pages":REPL$[5] = HTMLLST$
995 LBL$[6] = "date":REPL$[6] = ""
997 LBL$[7] = "postlist":REPL$[7] = "<a href='allposts.htm'>All Posts</a>"
1000 REM ======================
1001 REM Process pages
1000 REM ======================
1120 FOR FINDEX = 1 TO PAGECNT
1125     PRINT "Processing ";PAGES$[FINDEX];"..."
1130     TFILE$ = PAGEDIR$ + "\" + PAGES$[FINDEX]
1135     PAGET$ = PAGETIT$[FINDEX]
1140     OUTFILE$ = DESTDIR$ + "\" + LEFT$(PAGES$[FINDEX], LEN(PAGES$[FINDEX])-3) + "HTM"
1150     GOSUB 6000
1160 NEXT FINDEX
1200 REM ======================
1201 REM Process posts
1202 REM ======================
1205 ERASE SFL$,TIT$
1210 DIM SFL$[POSTCNT], TIT$[POSTCNT]
1215 FOR I = 1 TO POSTCNT:SFL$[I] = POSTS$[I]:TIT$[I] = POSTTIT$[I]:NEXT I
1217 LC = POSTCNT
1220 FOR FINDEX = 1 TO POSTCNT
1225     PRINT "Processing ";POSTS$[FINDEX];"..."
1230     DIREC$ = POSTDIR$
1240     OUTFILE$ = DESTDIR$ + "\" + LEFT$(POSTS$[FINDEX], LEN(POSTS$[FINDEX])-3) + "HTM"
1250     GOSUB 5000
1260 NEXT FINDEX
1300 REM ======================
1301 REM Deploy static files
1302 REM ======================
1305 PRINT "Deploying static files..."
1310 SRCD$ = STATICDIR$
1320 DESTD$ = DESTDIR$ + "\STATIC"
1330 SHELL "MKDIR "+DESTD$
1340 GOSUB 21000
1400 REM ======================
1401 REM Index page
1402 REM ======================
1410 SRCD$ = DESTDIR$ + "\" + LEFT$(POSTS$[POSTCNT], LEN(POSTS$[POSTCNT])-3) + "HTM"
1420 DESTD$ = DESTDIR$ + "\INDEX.HTM"
1430 PRINT "Creating index.htm from latest post..."
1440 SHELL "COPY "+SRCD$+" "+DESTD$
1500 REM ======================
1501 REM List of all posts
1502 REM ======================
1505 PRINT "Generating a list of posts..."
1510 PAGET$ = "All Posts"
1520 ERASE URLS$, LBLS$
1530 DIM URLS$[POSTCNT]
1540 DIM LBLS$[POSTCNT]
1550 FOR FINDEX = 1 TO POSTCNT
1560     URLS$[FINDEX] = POSTS$[FINDEX]:LBLS$[FINDEX] = POSTTIT$[FINDEX]
1570 NEXT FINDEX
1580 URLCOUNT = POSTCNT
1590 GOSUB 19100
1600 HTMLTEXT$ = "<h1>List of All Posts</h1>" + HTMLLST$
1610 OUTFILE$ = DESTDIR$ + "\ALLPOSTS.HTM"
1620 GOSUB 6500
1990 PRINT "Site Generation Complete."
1999 END